Originally Posted by
alal
Till now - No luck in even figuring out how to fix the registry (I hardly go there even on my desktop and am not touching that until I know how to make any entries in the system i.e. how to do text entry using the touchscreen - there is no onscreen keyboard)
Remember you were asked to find out what file loacted at SD-card will be accepted and executed when device starts up. In case you got it, you can use MortScript to change device's USB-mode to ActiveSync-mode, as the code snippet as following will demonstrate:
Code:
// USB-Mode-Selector.mscr
// This script toggles between USB ActiveSync mode, USB Mass Storage mode and USB RNDIS mode, as well as makes the change permanent
Local()
ID_USBFN_SERIAL=1
ID_USBFN_MASS=2
ID_USBFN_RNDIS=3
REGKEY_USBFN_SERIAL="Drivers\USB\FunctionDrivers\Serial_Class"
REGKEY_USBFN_MASS="Drivers\USB\FunctionDrivers\Mass_Storage_Class"
REGKEY_USBFN_RNDIS="Drivers\USB\FunctionDrivers\RNDIS"
hint="^NL^Select device's USB-mode ...^NL^"
If(RegKeyExists("HKLM",REGKEY_USBFN_SERIAL)&&RegKeyExists("HKLM",REGKEY_USBFN_MASS)&&RegKeyExists("HKLM",REGKEY_USBFN_RNDIS))
selectables=Array("Serial","Mass Storage","RNDIS")
ElseIf(RegKeyExists("HKLM",REGKEY_USBFN_SERIAL)&&RegKeyExists("HKLM",REGKEY_USBFN_MASS))
selectables=Array("Serial","Mass Storage")
EndIf
If(IsEmpty(selectables))
SleepMessage(5,"This feature is NOT supported by your device!")
Exit
EndIf
changed=0
Choice("USB-Mode Selector",hint,selectables)
Case ID_USBFN_SERIAL:
changed=@ChangeUSBToMode("Serial_Class")
If(changed)
CreateShortcut("\Windows\Startup\StartActiveSync.lnk","\Windows\repllog.exe",0)
EndIf
Case ID_USBFN_MASS:
changed=@ChangeUSBToMode("Mass_Storage_Class")
If(changed)
Delete("\Windows\Startup\StartActiveSync.lnk")
EndIf
Case ID_USBFN_RNDIS:
changed=@ChangeUSBToMode("RNDIS")
If(changed)
Delete("\Windows\Startup\StartActiveSync.lnk")
EndIf
EndChoice
If(changed)
SleepMessage(5,"Device now will re-bootet thus change made takes effect...")
Reset
EndIf
Exit
Sub ChangeUSBToMode(class)
Local()
changed=0
If(NOT IsEmpty(class))
REGPTH="Drivers\USB\FunctionDrivers"
REGKEY="DefaultClientDriver"
If(RegRead("HKLM",REGPTH,REGKEY) NE class)
// Set USB mode as desired
RegWriteString("HKLM",REGPTH,REGKEY,class)
Sleep(1000)
changed=1
EndIf
EndIf
Return(changed)
EndSub
After having changed USB-mode to "Serial_Class" (AKA ActiveSync) you can work on your device's registry from desktop (i.e. CeRegEditor).
Bookmarks